home *** CD-ROM | disk | FTP | other *** search
/ The Glitch Apple Disk Collection / 2014.glitch.apple.collection.zip / indexed / EXODUSCS.DSK / WIZ FIX.bas < prev   
BASIC Source File  |  2014-09-09  |  15KB  |  185 lines
  1. 1  REM <CTRL-M><CTRL-M><CTRL-M>=====================<CTRL-M><CTRL-M>      WIZ  FIX<CTRL-M>        FROM<CTRL-M>   (IN)CIDER  MAG<CTRL-M>    AUGUST  1983<CTRL-M>     PP 61 - 72<CTRL-M><CTRL-M>    INCODED  BY:<CTRL-M>       CLKAY<CTRL-M>====================<CTRL-M><CTRL-M><CTRL-M><CTRL-M><CTRL-M><CTRL-M><CTRL-M><CTRL-M><CTRL-M><CTRL-M>
  2. 2  REM <CTRL-M><CTRL-M><CTRL-M>      WIZARDRY CHARACTER UTILITY<CTRL-M><CTRL-M><CTRL-M><CTRL-M><CTRL-M>
  3. 3  REM <CTRL-M><CTRL-M><CTRL-M>********************<CTRL-M><CTRL-M>    WRITTEN  BY:<CTRL-M><CTRL-M>    KERRY J LANZ<CTRL-M><CTRL-M>********************<CTRL-M><CTRL-M><CTRL-M><CTRL-M><CTRL-M>
  4. 101  HOME 
  5. 105  HIMEM: 38000
  6. 110  DIM N$(20),TRK(20),SEC(20),T$(140)
  7. 115  GOSUB 800
  8. 120  GOSUB 700: GOTO 400
  9. 200  REM <CTRL-M><CTRL-M>IDENTIFY CHARACTER<CTRL-M><CTRL-M><CTRL-M>
  10. 205 P$ = "": FOR MAP = BASE +17 TO BASE +31:P$ = P$ + CHR$( PEEK(MAP)): NEXT 
  11. 210 L$ =  STR$( PEEK(BASE +200)) +"-EAST " + STR$( PEEK(BASE +202)) +"-NORTH LEVEL-" + STR$( PEEK(BASE +204))
  12. 220 R =  PEEK(BASE +34):C =  PEEK(BASE +36):S =  PEEK(BASE +40):O =  PEEK(BASE +42)
  13. 225 Y1 =  PEEK(BASE +38):Y2 =  PEEK(BASE +39):OL =  INT((Y1 +Y2 *256)/52)
  14. 230 C1 =  PEEK(BASE +44):C2 =  PEEK(BASE +45):C3 =  PEEK(BASE +46):C4 =  PEEK(BASE +47)
  15. 231 ST = C1 - INT(C1/32) *32
  16. 232 IQ =  INT(C1/32) +(C2 - INT(C2/4) *4) *8
  17. 233 PI =  INT(C2/4) -32 * INT(C2/128)
  18. 234 VI = C3 - INT(C3/32) *32
  19. 235 AG =  INT(C3/32) +(C4 - INT(C4/4) *4) *8
  20. 236 LU =  INT(C4/4) -32 * INT(C4/128)
  21. 240 G1 =  PEEK(BASE +52):G2 =  PEEK(BASE +53):G3 =  PEEK(BASE +54):G4 =  PEEK(BASE +55)
  22. 241 CASH = G1 +(G2 *256) +((G3 +(G4 *256)) *10000)
  23. 245 E1 =  PEEK(BASE +124):E2 =  PEEK(BASE +125):E3 =  PEEK(BASE +126):E4 =  PEEK(BASE +127)
  24. 246 EP = E1 +(E2 *256) +((E3 +(E4 *256)) *10000)
  25. 250 LE =  PEEK(BASE +132) +( PEEK(BASE +133) *256):PH =  PEEK(BASE +134):TH =  PEEK(BASE +136):AC =  PEEK(BASE +176): IF  PEEK(BASE +177) >0  THEN AC = (AC -256)
  26. 255  FOR K = 1 TO 7:MAP = BASE +144 +(2 *K):M(K) =  PEEK(MAP): NEXT 
  27. 260  FOR K = 1 TO 7:MAP = BASE +158 +(2 *K):P(K) =  PEEK(MAP): NEXT 
  28. 265  RETURN 
  29. 300  REM  <CTRL-M><CTRL-M>PRINT CHARACTER<CTRL-M><CTRL-M><CTRL-M>
  30. 305  HOME 
  31. 310  PRINT N$(A),O$(0);"  ";R$(R);"  ";C$(C): PRINT "PASSWORD==> ";P$: PRINT 
  32. 315  PRINT " STRENGTH "; SPC( ST <10);ST; SPC( 5);"GOLD ";CASH
  33. 320  PRINT "     I Q  "; SPC( IQ <10);IQ; SPC( 6);"EXP ";EP
  34. 325  PRINT "    PIETY "; SPC( PI <10);PI
  35. 330  PRINT " VITALITY "; SPC( VI <10);VI; SPC( 4);"LEVEL ";LE; SPC( 6);"AGE ";OL
  36. 335  PRINT "  AGILITY "; SPC( AG <10);AG; SPC( 5)"HITS ";PH;"/";TH; SPC( 2);"AC ";AC
  37. 340  PRINT "     LUCK "; SPC( LU <10);LU; SPC( 3);"STATUS ";S$(S): PRINT 
  38. 342  PRINT "     MAGE ";M(1);"/";M(2);"/";M(3);"/";M(4);"/";M(5);"/";M(6);"/";M(7)
  39. 344  PRINT "   PRIEST ";P(1);"/";P(2);"/";P(3);"/";P(4);"/";P(5);"/";P(6);"/";P(7)
  40. 346  PRINT : PRINT "LOCATION: ";L$
  41. 348  FOR K = 1 TO 39: PRINT "*";: NEXT : RETURN 
  42. 350  REM <CTRL-M><CTRL-M>CHOICES<CTRL-M><CTRL-M><CTRL-M>
  43. 353  PRINT 
  44. 355  PRINT "A-LIFE       E-LEVEL+1    I-EXPERIENCE"
  45. 360  PRINT "B-CASTLE     F-HIT POINTS J-GOLD"
  46. 365  PRINT "C-IDENTIFY   G-M SPELLS   K-YOUTH"
  47. 370  PRINT "D-UNCURSE    H-P SPELLS   L-QUALITIES"
  48. 375  PRINT " <2> P.2,REMAKE  <3> P.3,TRADING POST"
  49. 377  PRINT " <ESC> ROSTER, CHANGES CANCELLED"
  50. 380  PRINT " <RET> ROSTER, CHANGES PERMANENT"
  51. 385  PRINT " CTRL-P PRINT-OUT OF CHARACTER": RETURN 
  52. 400  REM <CTRL-M><CTRL-M>MAIN PROGRAM<CTRL-M><CTRL-M><CTRL-M>
  53. 405  GOSUB 200: GOSUB 300: GOSUB 350: POKE 35,15
  54. 410  VTAB 15: HTAB 19: POKE  -16368,0: GET B$:B =  ASC(B$)
  55. 415  IF B = 27  THEN  GOTO 120
  56. 416  IF B = 50  THEN 600
  57. 417  IF B = 51  THEN 650
  58. 420  IF B < >16  THEN 430
  59. 422  VTAB 14: HTAB 1: PRINT " ->START PRINTER AND PRESS ANY KEY<-";: GET A$: PRINT  CHR$(4): PRINT  CHR$(4)"PR#1"
  60. 424  PRINT : FOR K = 1 TO 40: PRINT "*";: NEXT : PRINT : GOSUB 300: PRINT : GOSUB 696: GOSUB 348: PRINT : PRINT  CHR$(4): PRINT  CHR$(4)"PR#0"
  61. 426  GOSUB 300: GOTO 410
  62. 430  IF B = 13  THEN  POKE 47092,2: CALL 768: POKE 47092,1: GOTO 120
  63. 435  IF B <65  OR B >76  THEN  GOTO 410
  64. 440 B = B -64
  65. 445  ON B GOSUB 500,505,510,515,520,525,530,535,540,545,550,555: GOSUB 200: GOSUB 300: GOTO 410
  66. 500  POKE BASE +40,0: POKE BASE +41,0: RETURN 
  67. 505  POKE BASE +32,0: FOR K = 200 TO 205: POKE BASE +K,0: NEXT : RETURN 
  68. 510  FOR MAP = BASE +64 TO BASE +120  STEP 8: POKE MAP,1: NEXT : FOR K = 8 TO 1  STEP  -1: IF  PEEK(BASE +58 +(8 *K)) = 0  THEN  NEXT :K = 0
  69. 511  POKE BASE +58,K: RETURN 
  70. 515  FOR MAP = BASE +62 TO BASE +118  STEP 8: POKE MAP,0: POKE MAP -2,0: NEXT : RETURN 
  71. 520 K =  PEEK(BASE +132): IF K <254  THEN  POKE BASE +130,K +1: POKE BASE +132,K +1: RETURN 
  72. 521  RETURN 
  73. 525 K =  PEEK(BASE +136): IF K <245  THEN  POKE BASE +134,K +10: POKE BASE +136,K +10
  74. 526  RETURN 
  75. 530  POKE BASE +138,255: POKE BASE +139,255: POKE BASE +140,255: FOR K = 1 TO 7:MAP = BASE +144 +(K *2): POKE MAP,9: NEXT : RETURN 
  76. 535  POKE BASE +140,255: POKE BASE +141,255: POKE BASE +142,255: POKE BASE +143,255: POKE BASE +144,7: FOR K = 1 TO 7:MAP = BASE +158 +(K *2): POKE MAP,9: NEXT : RETURN 
  77. 540  IF  PEEK(BASE +126) <254  THEN  POKE BASE +126, PEEK(BASE +126) +1
  78. 541  RETURN 
  79. 545  IF  PEEK(BASE +54) <254  THEN  POKE BASE +54, PEEK(BASE +54) +1
  80. 546  RETURN 
  81. 550  POKE BASE +38,170: POKE BASE +39,3: RETURN 
  82. 555  POKE BASE +44,82: POKE BASE +45,74: POKE BASE +46,82: POKE BASE +47,74: RETURN 
  83. 600  REM <CTRL-M><CTRL-M>RECREATE CHARACTER<CTRL-M><CTRL-M><CTRL-M>
  84. 602  TEXT : HOME 
  85. 605  PRINT N$(A),O$(O);" ";R$(R);" ";C$(C): PRINT : FOR K = 1 TO 40: PRINT "*";: NEXT : PRINT 
  86. 610  PRINT "A-GOOD         D-HUMAN       I-FIGHTER"
  87. 611  PRINT "B-NEUTRAL      E-ELF         J-MAGE"
  88. 612  PRINT "C-EVIL         F-DWARF       K-PRIEST"
  89. 613  PRINT  TAB( 16)"G-GNOME       L-THIEF"
  90. 614  PRINT  TAB( 16)"H-HOBBIT      M-BISHOP"
  91. 615  PRINT  TAB( 30)"N-SAMURAI": PRINT  TAB( 30)"O-LORD": PRINT  TAB( 30)"P-NINJA"
  92. 616  PRINT : PRINT " <RET>  RETURN TO P.1"
  93. 620  VTAB 16: HTAB 19: POKE  -16386,0: GET B$:B =  ASC(B$): IF B = 13  THEN 405
  94. 621 B = B -64: IF B <0  OR B >16  THEN 620
  95. 622  IF B <4  THEN 630
  96. 623  IF B <9  THEN 635
  97. 624  GOTO 640
  98. 630 O = B: POKE (BASE +42),O: GOTO 602
  99. 635 R = B -3: POKE (BASE +34),R: GOTO 602
  100. 640 C = B -9: POKE (BASE +36),C: GOTO 602
  101. 650  REM <CTRL-M><CTRL-M>TRADING POST<CTRL-M><CTRL-M><CTRL-M>
  102. 651  GOSUB 510: GOSUB 515: TEXT 
  103. 652  HOME :T(0) =  PEEK(BASE +58): GOSUB 695
  104. 653  FOR K = 1 TO 40: PRINT "*";: NEXT : PRINT 
  105. 654  PRINT "YOU MAY CHOOSE:": PRINT " A. BASICS": PRINT " B. BETTER STUFF"
  106. 655  PRINT " C. REALLY GOOD STUFF": PRINT " D. PROVING GROUNDS ONLY": PRINT " E. KOD ONLY, PART 1"
  107. 656  PRINT " F. KOD ONLY, PART 2": PRINT " G. DROP SOMETHING": PRINT : PRINT "<RET> RETURN TO P.1"
  108. 657  VTAB 22: HTAB 19: POKE  -16368,0: GET B$:B =  ASC(B$): IF B = 13  THEN 405
  109. 658  IF B <65  OR B >71  THEN 657
  110. 659 B = B -64: ON B GOTO 670,671,672,673,674,675,660
  111. 660  VTAB 22: HTAB 1: PRINT "TYPE NUMBER OF OBJECT TO DROP: ";: POKE  -16368,0: GET B$:B =  ASC(B$): IF B <49  OR B >56  THEN 660
  112. 661 B = B -48: FOR K = B TO 8: POKE BASE +58 +8 *K, PEEK(BASE +66 +8 *K): NEXT : POKE BASE +122,0
  113. 662  POKE BASE +58, PEEK(BASE +58) -1: GOTO 652
  114. 670 TT$ = "BASIC ITEM":TLO = 1:THI = 15: GOTO 680
  115. 671 TT$ = "BETTER ITEMS":TLO = 33:THI = 15: GOTO 680
  116. 672 TT$ = "REALLY GOOD ITEMS":TLO = 64:THI = 14: GOTO 680
  117. 673 TT$ = "PROVING GROUNDS ONLY":TLO = 130:THI = 3: GOTO 680
  118. 674 TT$ = "KNIGHT OF DIAMONDS ONLY":TLO = 94:THI = 14: GOTO 680
  119. 675 TT$ = "KNIGHT OF DIAMONDS ONLY":TLO = 124:THI = 2: GOTO 680
  120. 680  HOME : HTAB 20 - LEN(TT$) *.5: PRINT TT$: PRINT 
  121. 681  FOR K = TLO TO TLO +THI: PRINT K;"-";T$(K): NEXT : VTAB 3
  122. 682  FOR K = TLO +THI +1 TO TLO +1 +(THI *2): HTAB 20: PRINT K;"-";T$(K): NEXT 
  123. 683  VTAB 19: FOR K = 1 TO 40: PRINT "*";: NEXT :
  124. 684 T(0) =  PEEK(BASE +58): PRINT "YOU HAVE ";T(0);" OBJECTS.": IF T(0) >7  THEN  PRINT "YOU HAVE NO MORE ROOM.": FOR K = 1 TO 1500: NEXT : GOTO 652
  125. 685  PRINT "YOU MAY CHOOSE AN OBJECT BY NUMBER, OR  PRESS <RETURN> TO GO TO TRADING POST."
  126. 686  VTAB 23: HTAB 19: INPUT "";B$: IF B$ = ""  THEN 652
  127. 687 B =  VAL(B$): IF B <TLO  OR B >TLO +1 +(THI *2)  THEN 686
  128. 688  IF B >129  THEN B = B -36
  129. 689  POKE BASE +58,T(0) +1: POKE BASE +58 +(8 *(T(0) +1)),B: GOTO 680
  130. 695  PRINT  TAB( 14)"TRADING POST": PRINT : PRINT C$(C);" ";N$(A);": ";T(0);" OBJECTS"
  131. 696  FOR K = 1 TO 8:T(K) =  PEEK(BASE +58 +8 *K): NEXT 
  132. 697  PRINT : FOR K = 1 TO 8  STEP 2: PRINT K;"-";T$(T(K)); SPC( 17 - LEN(T$(T(K))));K +1;"-";T$(T(K +1)): NEXT : RETURN 
  133. 700  REM <CTRL-M><CTRL-M>ROSTER<CTRL-M><CTRL-M><CTRL-M>
  134. 705  TEXT : HOME : GOSUB 750: PRINT : PRINT : PRINT "THESE ARE THE CHARACTERS ON YOUR BACK-UPWIZARDRY DISK.  YOUR OPTIONS NOW ARE:": PRINT 
  135. 710  PRINT "'A' TO 'T' CHOOSE A CHARACTER BY LETTER <ESCAPE>  ENDS THE PROGRAM              <CTRL-P>  PRINTS OUT THE ROSTER": PRINT 
  136. 715  VTAB 22: HTAB 19: GET A$:A =  ASC(A$): IF A = 27  THEN 840
  137. 720  IF A < >16  THEN  GOTO 730
  138. 722  PRINT : PRINT  TAB( 4)"START PRINTER AND PRESS ANY KEY. ";: GET A$: PRINT  CHR$(4)"PR#1"
  139. 724  PRINT : GOSUB 750: PRINT : PRINT  CHR$(4)"PR#0"
  140. 726  GOTO 705
  141. 730  IF A <65  OR A >84  THEN  GOTO 715
  142. 735 A = A -64: POKE 47084,TRK(A): POKE 47085,SEC(A): CALL 768: RETURN 
  143. 750  PRINT  SPC( 8)"WIZARDRY ROSTER": FOR K = 1 TO 32: PRINT "-";: NEXT : PRINT 
  144. 755  FOR K = 1 TO 20  STEP 2: PRINT  CHR$(K +64);". "; LEFT$(N$(K),12),; CHR$(K +65);". "; LEFT$(N$(K +1),12): NEXT : RETURN 
  145. 800  REM <CTRL-M><CTRL-M>TITLE PAGE<CTRL-M><CTRL-M><CTRL-M>
  146. 810  VTAB 5: HTAB 16: INVERSE : PRINT "+      +": VTAB 6: HTAB 16: PRINT "WIZ  FIX": VTAB 7: HTAB 16: PRINT "+      +": NORMAL : PRINT : PRINT 
  147. 825  PRINT : PRINT "  MAKE A BACK-UP DISK OF YOUR CHARACTERSUSING THE WIZARDRY UTILITIES.  WIZ FIX  WILL HELP YOU DO ALL MANNER OF MAGICS.  USE ONLY THE BACK UP!!!!!!!!!!": PRINT  TAB( 10)"INSERT BACK-UP DISK. "
  148. 830  SPEED= 255: GOSUB 900: PRINT  TAB( 7)"PRESS  <RETURN>  TO BEGIN ";: POKE  -16368,0: GET A$: IF A$ =  CHR$(13)  THEN  GOTO 850
  149. 840  HOME : VTAB 11: HTAB 16: PRINT "FAREWELL": PRINT : PRINT : PRINT : PRINT : PRINT : END 
  150. 850  FOR K = 1 TO 20: POKE 47084,TRK(K): POKE 47085,SEC(K): CALL 768:N$(K) = "": FOR L = 1 TO 15:N$(K) = N$(K) + CHR$( PEEK(BASE +L)): NEXT : NEXT : RETURN 
  151. 900  REM <CTRL-M><CTRL-M>INITIALIZATION<CTRL-M><CTRL-M><CTRL-M>
  152. 905  POKE 768,32: POKE 769,227: POKE 770,3: POKE 771,76: POKE 772,217: POKE 773,3: POKE 47083,0: POKE 47091,0: POKE 47092,1
  153. 906 BASE = 38000
  154. 907  POKE 47088,BASE - INT(BASE/256) *256: POKE 47089, INT(BASE/256)
  155. 910  FOR K = 1 TO 5: READ R$(K): NEXT : FOR K = 0 TO 7: READ C$(K): NEXT : FOR K = 0 TO 7: READ S$(K): NEXT : FOR K = 1 TO 3: READ O$(K): NEXT : FOR K = 1 TO 20: READ TRK(K),SEC(K): NEXT 
  156. 911 T$(0) = " ": FOR K = 1 TO 136: READ T$(K): NEXT 
  157. 915  RETURN 
  158. 930  DATA  HUMAN,ELF,DWARF,GNOME,HOBBIT
  159. 931  DATA  FIGHTER,MAGE,PRIEST,THIEF,BISHOP,SAMURAI,LORD,NINJA
  160. 932  DATA  OK,AFRAID,ASLEEP,PARALYZED,STONED,DEAD,ASHES,LOST FOREVER
  161. 933  DATA  GOOD,NEUTRAL,EVIL
  162. 934  DATA  0,0,0,13,0,11,0,9,0,7,0,5,0,3,0,1,1,0,1,13,1,11,1,9,1,7,1,5,1,3,1,1,2,0,2,13,2,11,2,9
  163. 935  DATA  LONG SWORD,SHORT SWORD,ANOINTED MACE,ANOINTED FLAIL,STAFF,DAGGER,SMALL SHIELD,L. SHIELD,ROBES,LEATHER ARMOR
  164. 936  DATA  CHAIN MAIL,BREAST PLATE,PLATE MAIL,HELM,DIOS POTION,LATUMOFIS POTION,LONG SWORD +1,SHOR SWORD +1,MACE+1,STAFF OF MOGREF
  165. 937  DATA  KANTINO SCROLL,LEATHER+1,CHAIN MAIL +1,PLATE MAIL +1,SHIELD +1,BREAST PLATE +1,BADIOS SCROLL,HALITO SCROLL,LONG SWORD -1,SHORT SWORD -1
  166. 938  DATA  MACE -1,STAFF +2,DRAGON SLAYER,HELM +1,LEATHER-1,CHAIN -1,BREAST PLATE -1,SHIELD -1,JEWELED AMULET,BADIOS SCROLL
  167. 939  DATA  SOPIC POTION,L. SWORD +2,S. SWORD +2,MACE+2,LOMILWA SCROLL,DILTO SCROLL,COPPER GLOVES,LEATHER +2,CHAIN +2,PLATEMAIL +2
  168. 940  DATA  SHIELD +2,HELM +2(EVIL),DIAL POTION,PORFIC RING,WERE SLAYER,MAGE MASHER,MACE PRO POISON,MONTINO STAFF,BLADE CUSINART',MANIFO AMULET
  169. 941  DATA  ROD OF FLAME,EVIL CHAIN +2,NEUT P-MAIL +2,EVIL SHIELD +3,MAKANITO AMULET,MALOR DIADEM,BADIAL SCROLL,SHORT SWORD -1,DAGGER +2,MACE -2
  170. 942  DATA  STAFF -2,DAGGER OF SPEED,CURSED ROBE,LEATHER -2,CHAIN -2,BREAST PLATE -2,SHIELD -2,CURSED HELMET,BREAST PLATE +2,SILVER GLOVES
  171. 943  DATA  EVIL SWORD +3,EVIL SSWORD +3,THIEVES DAGGER,BREAST PLATE +3,LORDS GARB,MURASAMA BLADE,SHURIKEN,CHAIN PRO FIRE,EVIL PLATE +3,SHIELD +3
  172. 944  DATA  RING OF HEALING,RING PRO UNDEAD,DEADLY RING,ROD OF RISING,AMULET OF COVER,ROBE +3,WINTER MITTENS,NCKLCE PRO MAGIC,STAFF OF LIGHT,LONG SWORD +5
  173. 945  DATA  SWINGING SWORD,FRIEST PUNCHER,PRIEST'S MACE,SWINGING SSWORD,RING PRO FIRE,CURSED PLATE +1,PLATE MAIL +5,STAFF OF CURING,RING OF REGEN,METAMORPH RING
  174. 946  DATA  STONE STONE,DREAMER'S STONE,DAMIEN STONE,GREAT MAGE WAND,COIN OF POWER,STONE OF YOUTH,MIND STONE,STONE OF PIETY,BLARNEY STONE,AMULET OF SKILL
  175. 947  DATA  AMULET OF SKILL,GREAT MAGE WAND,COIN OF POWER,STAFF OF GNILDA,HRATHNIR,KOD HELMET,KOD SHIELD,KOD GAUNTLETS,KOD ARMOR
  176. 948  DATA  WERDNA'S AMULET,BEAR STATUE,FROG STATUE,BRONZE KEY,SILVER KEY,GOLD KEY,BLUE RIBBON
  177. 1000  REM <CTRL-M><CTRL-M>A     POSITION OF CHAR ON ROSTER<CTRL-M>A$    KEYBOARD COMMAND<CTRL-M>AC    ARMOR CLASS<CTRL-M>AG    AGILITY<CTRL-M>B$,B  KEYBOARD INPUT<CTRL-M>BASE  STARTING LOC IN RAM OF CHARACTER<CTRL-M><CTRL-M>
  178. 1001  REM <CTRL-M><CTRL-M>C$(C) CLASS FROM CLASS LABEL ARRAY<CTRL-M>C1-C4 CHARACTERISTIC BYTES<CTRL-M>CASH  AMOUNT OF GOLD<CTRL-M>E1-E4 EXPERIENCE BYTES<CTRL-M>EP    EXPERIENCE POINTS<CTRL-M>G1-G4 GOLD BYTES<CTRL-M><CTRL-M>
  179. 1002  REM <CTRL-M><CTRL-M>IQ    IQ OF CHARACTEER<CTRL-M>K     MISCELLANEOUS COUNTER<CTRL-M>L$    LOCATION RELATIVE TO CASTLE<CTRL-M>LE    LEVEL OF CHARACTER<CTRL-M>LU    LUCK OF CHARACTER<CTRL-M>M     MAGE SPELLS, NUMBER PER LEVEL<CTRL-M><CTRL-M>
  180. 1003  REM <CTRL-M><CTRL-M>MAP   MISCELLANEOUS<CTRL-M>N$    ARRAY OF 20 CHARACTER NAMES<CTRL-M>O$(O) ORIENTATION, FROM ARRAY OF LABELS<CTRL-M>OL    YEARS OLD<CTRL-M>P$    PASSWORD<CTRL-M>P     PRIEST SPELLS, NUMBER PER LEVEL<CTRL-M><CTRL-M>
  181. 1004  REM <CTRL-M><CTRL-M>PH    PRESENT HIT POINT<CTRL-M>PI    PIETY OF CHARACTER<CTRL-M>R$(R) RACE, FROM ARRAY OF LABELS<CTRL-M>S$(S) STATUS, FROM ARRAY OF LABELS<CTRL-M>SEC   SECTORS ON DISK<CTRL-M>ST    STRENGTH OF CHARACTER<CTRL-M><CTRL-M>
  182. 1005  REM <CTRL-M><CTRL-M>T$    ARRAY OF OBJECTS<CTRL-M>T     VALUES IN THE 8 OBJECT BYTES<CTRL-M>TLO   LOW PARAMETER OF OBJECT LIST<CTRL-M>THI   HIGH PARAMETERS OF OBJECT LIST<CTRL-M>TT$   TITLES OF OBJECT LIST SECTIONS<CTRL-M><CTRL-M>
  183. 1006  REM <CTRL-M><CTRL-M>TRK   TRACKS ON DISK<CTRL-M>VI    VITALITY OF CHARACTER<CTRL-M>Y1-Y2 AGE BYTES IN WEEKS
  184. 1010  REM <CTRL-M><CTRL-M>==========================<CTRL-M><CTRL-M>THE SALE OF THIS PROGRAM IS<CTRL-M>PAYMENT FOR ENCODING TIME ONLY<CTRL-M>AND IN NO WAY IMPLIES THAT CLKAY<CTRL-M>WAS THE AUTHOR OR CREATER OF<CTRL-M>          WIZ FIX<CTRL-M><CTRL-M>==========================<CTRL-M>
  185. 1011  REM <CTRL-M><CTRL-M>=========================<CTRL-M><CTRL-M>PROGRAM AUTHORED AND WRITTEN BY<CTRL-M>        KERRY J LANZ<CTRL-M><CTRL-M>=========================